# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>

pkgbase=pulseaudio-git
pkgname=(pulseaudio-git libpulse-git pulseaudio-{zeroconf,lirc,jack,bluetooth,equalizer,rtp}-git)
pkgdesc="A featureful, general-purpose sound server (from git)"
pkgver=14.99.2+1+g36fcfeb21
pkgrel=1
arch=(x86_64)
url="https://www.freedesktop.org/wiki/Software/PulseAudio/"
license=(GPL)
makedepends=(libasyncns libcap attr libxtst libsm libsndfile rtkit libsoxr
             speexdsp tdb systemd dbus avahi bluez bluez-libs jack2 sbc
             lirc openssl fftw orc gtk3 webrtc-audio-processing check git meson
             xmltoman valgrind doxygen)
options=(!strip debug)
source=("git+https://gitlab.freedesktop.org/pulseaudio/pulseaudio.git")
sha256sums=('SKIP')

pkgver() {
  cd pulseaudio
  git describe --tags | sed 's/^v//;s/-/+/g'
}

prepare() {
  cd pulseaudio

  # Freeze version before patching
  ./git-version-gen doesnt-exist >.tarball-version
}

build() {
  local meson_options=(
    -D stream-restore-clear-old-devices=true
    -D pulsedsp-location='/usr/\$LIB/pulseaudio'
    -D udevrulesdir=/usr/lib/udev/rules.d
    -D bluez5-gstreamer=disabled
    -D elogind=disabled
    -D tcpwrap=disabled
  )

  arch-meson pulseaudio build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
  ninja -C build test-daemon
}

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

package_pulseaudio-git() {
  depends=("libpulse-git=$pkgver-$pkgrel" rtkit libltdl speexdsp tdb orc libsoxr
           webrtc-audio-processing libxtst)
  optdepends=('pulseaudio-alsa: ALSA configuration (recommended)'
              'pulseaudio-zeroconf-git: Zeroconf support'
              'pulseaudio-lirc-git: IR (lirc) support'
              'pulseaudio-jack-git: Jack support'
              'pulseaudio-bluetooth-git: Bluetooth support'
              'pulseaudio-equalizer-git: Graphical equalizer'
              'pulseaudio-rtp-git: RTP and RAOP support')
  backup=(etc/pulse/{daemon.conf,default.pa,system.pa})
  install=pulseaudio.install
  provides=(pulseaudio)
  conflicts=(pulseaudio)
  replaces=('pulseaudio-xen-git<=9.0+113+g058f223'
            'pulseaudio-gconf-git<=11.0+129+gba2b748d')

  local pulsever=$(cd pulseaudio; ./git-version-gen .tarball-version)
  while [[ $pulsever = *.*.* ]]; do
    pulsever=${pulsever%.*}
  done
  pulsever=${pulsever%%-*}

  meson install -C build --destdir "$pkgdir"

  cd "$pkgdir"

  # Superseded by socket activation
  sed -e '/autospawn/iautospawn = no' \
      -i etc/pulse/client.conf

  # Disable cork-request module, can result in e.g. media players unpausing
  # when there's a Skype call incoming
  sed -e 's|/usr/bin/pactl load-module module-x11-cork-request|#&|' \
      -i usr/bin/start-pulseaudio-x11

  # Required by qpaeq
  sed -e '/Load several protocols/aload-module module-dbus-protocol' \
      -i etc/pulse/default.pa

  rm -r etc/dbus-1

  # Split packages
  _pick libpulse etc/pulse/client.conf
  _pick libpulse usr/bin/pa{cat,ctl,dsp,mon,play,rec,record}
  _pick libpulse usr/lib/libpulse{,-simple,-mainloop-glib}.so*
  _pick libpulse usr/lib/{cmake,pkgconfig}
  _pick libpulse usr/lib/pulseaudio/libpulse{dsp,common-*}.so
  _pick libpulse usr/include
  _pick libpulse usr/share/man/man1/pa{cat,ctl,dsp,mon,play,rec,record}.1
  _pick libpulse usr/share/man/man5/pulse-client.conf.5
  _pick libpulse usr/share/bash-completion/completions/pa{cat,ctl,dsp,play,rec,record}
  _pick libpulse usr/share/bash-completion/completions/pulseaudio
  _pick libpulse usr/share/vala
  _pick libpulse usr/share/zsh

  local moddir=usr/lib/pulse-$pulsever/modules

  _pick zeroconf $moddir/libavahi-wrap.so
  _pick zeroconf $moddir/module-zeroconf-{publish,discover}.so
  _pick zeroconf $moddir/module-raop-discover.so

  _pick lirc $moddir/module-lirc.so

  _pick jack $moddir/module-jack-{sink,source}.so
  _pick jack $moddir/module-jackdbus-detect.so

  _pick bluetooth $moddir/libbluez5-util.so
  _pick bluetooth $moddir/module-bluetooth-{discover,policy}.so
  _pick bluetooth $moddir/module-bluez5-{discover,device}.so

  _pick equalizer $moddir/module-equalizer-sink.so
  _pick equalizer usr/bin/qpaeq

  _pick rtp $moddir/lib{rtp,raop}.so
  _pick rtp $moddir/module-rtp-{send,recv}.so
  _pick rtp $moddir/module-raop-sink.so
}

package_libpulse-git() {
  pkgdesc="$pkgdesc (client library, from git)"
  depends=(dbus libasyncns libcap libxcb libsm libsndfile systemd)
  optdepends=('glib2: mainloop integration')
  provides=(libpulse{,-simple,-mainloop-glib}.so libpulse)
  license=(LGPL)
  backup=(etc/pulse/client.conf)
  conflicts=(libpulse)

  mv libpulse/* "$pkgdir"
}

package_pulseaudio-zeroconf-git() {
  pkgdesc="Zeroconf support for PulseAudio (from git)"
  depends=("pulseaudio-git=$pkgver-$pkgrel" avahi openssl)
  provides=(pulseaudio-zeroconf)
  conflicts=(pulseaudio-zeroconf)

  mv zeroconf/* "$pkgdir"
}

package_pulseaudio-lirc-git() {
  pkgdesc="IR (lirc) support for PulseAudio (from git)"
  depends=("pulseaudio-git=$pkgver-$pkgrel" lirc)
  provides=(pulseaudio-lirc)
  conflicts=(pulseaudio-lirc)

  mv lirc/* "$pkgdir"
}

package_pulseaudio-jack-git() {
  pkgdesc="Jack support for PulseAudio (from git)"
  depends=("pulseaudio-git=$pkgver-$pkgrel" jack)
  provides=(pulseaudio-jack)
  conflicts=(pulseaudio-jack)

  mv jack/* "$pkgdir"
}

package_pulseaudio-bluetooth-git() {
  pkgdesc="Bluetooth support for PulseAudio (from git)"
  depends=("pulseaudio-git=$pkgver-$pkgrel" bluez bluez-libs sbc)
  provides=(pulseaudio-bluetooth)
  conflicts=(pulseaudio-bluetooth)

  mv bluetooth/* "$pkgdir"
}

package_pulseaudio-equalizer-git() {
  pkgdesc="Graphical equalizer for PulseAudio (from git)"
  depends=("pulseaudio-git=$pkgver-$pkgrel" python-{pyqt5,dbus} fftw)
  provides=(pulseaudio-equalizer)
  conflicts=(pulseaudio-equalizer)

  mv equalizer/* "$pkgdir"
}

package_pulseaudio-rtp-git() {
  pkgdesc="RTP and RAOP support for PulseAudio (from git)"
  depends=("pulseaudio-git=$pkgver-$pkgrel")
  provides=(pulseaudio-rtp)
  conflicts=(pulseaudio-rtp)

  mv rtp/* "$pkgdir"
}

# vim:set sw=2 et: